有个朋友 做 某种小众音乐交换站的(他们那个行业的昵图网),需要用到付费下载。尝试过 防盗链,不太理想,最终使用了 Adodb.Stream 读取,直接输出。

解决了 盗版的问题,但是新的问题又来了。Adodb.Stream 这种方式 电脑还好说,大部分电脑浏览器都支持。移动端 很多 浏览器为了 加速读取,会多线程下载导致 文件无法正常读取。

抓包,发现增加了 HTTP头 HTTP_RANGE。隐约记得 之前读过 王大(王洪影)的 《深入解析 ASP核心技术》当中提到ASP多线程下载的问题,回家翻出来,最终还就真解决了。

为了 方便调用,直接写成了 一个 函数。没用王大的代码,感觉我自己的更美(自恋中…)。如有有需要的朋友需要,直接拿走即可,代码如下:

option explicit
 
'inputFile 需要下载的文件
'outputName 输出文件名,可以为空,为空时自动根据 inputFile 生成
Sub CreateDownloader(byval inputFile, byval outputName)
  Dim filePath
  filePath = Server.Mappath(inputFile)
  If outputName = "" Then outputName = Split(filePath, "\")(UBound(Split(filePath, "\")))
 
  '下载开始
  Dim AdoStream, bufferSize
  Set AdoStream = Server.CreateObject("Adodb.Stream") 'Adodb.Stream,实例变量名为了方便区分用大写
  bufferSize   = 2 * 1024 * 1024 '每次读取大小(byte) 2M
  AdoStream.Mode = 3 '1 读,2 写,3 读写
  AdoStream.Type = 1 '1 二进制,2 文本
  AdoStream.Open
  AdoStream.LoadFromFile(filePath) '载入文件
  Response.AddHeader "Content-Disposition", "attachment; filename=" & outputName '文件名
  Response.ContentType = "application/octet-stream" '通知浏览器接受的文件类型(可自己定义,很多种,但一般都用这个
 
  Dim httpRange,rangeStart,fileSize
  '获取 分段下载 请求
  httpRange = Request.ServerVariables("HTTP_RANGE")
  fileSize = AdoStream.size '文件总大小
 
  If httpRange = "" Then
    '不支持断点续传
    rangeStart = 0
  Else
    '支持断点续传
    httpRange = Mid(httpRange, 7)
    rangeStart = CLng(Split(httpRange, "-")(0))
 
    If rangeStart < 0 Or rangeStart >= fileSize Then
      '已经下载完毕
      Response.Status = "416 Requested range not satisfiable"
    Else
      Response.Status = "206 Partial Content"
      Response.AddHeader "Content-Range", "bytes " & rangeStart & "-" & (fileSize - 1) & "/" & fileSize
      AdoStream.Position = rangeStart
    End If
 
  End If
 
  Dim binaryBlock
 
  If Response.Status <> "416 Requested range not satisfiable" Then
    Response.AddHeader "Content-Length", fileSize - rangeStart '通知浏览器接收的文件大小
    binaryBlock = AdoStream.Read(bufferSize)
 
    Do While Lenb(binaryBlock) > 0 '循环读取直到读完为止
      Response.BinaryWrite binaryBlock '输出二进制数据流
      Response.Flush '立即发送(要求至少256字节),不加的话可能提示超过缓存区。
      binaryBlock = AdoStream.Read(bufferSize)
    Loop
 
  End If
 
  AdoStream.Close '关闭文件对象
  Set AdoStream = Nothing
  Response.End
End Sub

使用也非常简单,假如上面的代码保存到了 downloader.asp,直接引用即可:

<!--#include file="downloader.asp"-->
<%
  '创建下载
  call CreateDownloader("down/tools.rar", "")
   
  '创建下载并自定义文件名
  call CreateDownloader("down/tools.rar", "hello.rar")
%>

有图有真相:

到此这篇关于ASP下通过Adodb.Stream实现多线程下载大文件的文章就介绍到这了!

ASP下通过Adodb.Stream实现多线程下载大文件的更多相关文章

  1. asp中将字符串转数字的函数小结

    常常因为一些小地放的失误导致整个程序瘫痪.今天就遇到了.一个商城系统.因为计算整得我改了N久在此记下这些数据转换的函......

  2. ASP下通过Adodb.Stream实现多线程下载大文件

    有个朋友 做 某种小众音乐交换站的(他们那个行业的昵图网),需要用到付费下载。尝试过 防盗链,不太理想,最终使用了 ......

  3. 使用AJAX实现UTF8编码表单提交到GBK编码脚本无乱码的解决方法

    1、表单项目1 GBK编码格式用户采集单是GBK编码,通过GET/POST提交上来的数据也是GBK格式,无需做任何处......

  4. asp限制域名访问实现代码

    asp 设置只能指定域名可以使用此网站代码一 脚本之家原创<% myIp = ",127.0.0.1......

  5. asp判断某个文件是否存在的函数

    最近在写功能的时候需要判断某个文件是否存在,存在则调用,不存在则动态显示页面的功能,用到了下面的代码,特分享一下需要......

  6. asp(vbscript)中自定义函数的默认参数实现代码

    现代语言的函数中都可以带有默认参数,在vbscript系统内建的函数可以带有可选值(如常用的 split()等等),......

  7. ASP删除img标签的style属性只保留src的正则函数

    ASP去除img标签style属性只保留src'功能:将IMG代码格式化为<img src="XXX......

  8. ASP中常用的22个FSO文件操作函数整理

    在ASP中,FSO的意思是File System Object,即文件系统对象。我们将要操纵的计算机文件系统,在这里......

  9. msxml3.dll 错误 800c0019 系统错误:-2146697191解决方法

    一个asp后台使用了XMLHTTP组件的页面无法无法生成静态页面了,运行时提示"msxml3.dll 错误......

随机推荐

  1. Python优化机制:常量折叠

    英文:https://arpitbhayani.me/blogs/constant-folding-python作者......

  2. Android事件分发机制四:学了事件分发有什么用?

    前言Android事件分发机制已经来到第四篇了,在前三篇中:Android事件分发机制一:事件是如何到达activi......

  3. Asp.Net 加密解密

    #region DES加密解密 /// /// DES加密 /// /// 待加密字串 /// 32位Key值 ......

  4. python用700行代码实现http客户端

    本文用python在TCP的基础上实现一个HTTP客户端, 该客户端能够复用TCP连接, 使用HTTP1.1协议.一......

  5. [Java基础]——String类

    此篇博客主要整理Java中的String类的使用。一、String1.1 String 的定义上图是jdk中对......

  6. synchronized详解

    synchronized是Java多线程中元老级的锁,也是面试的高频考点,让我们来详细了解synchronized吧......

  7. python将YUV420P文件转PNG图片格式的两种方法

    方法一:import osimport cv2 as cvimport numpy as np# 读取yuv420p......

  8. C# 实现在当前目录基础上找到上一层目录

    其实很简单也很无脑,但却很实用,就是使用拆字符串的方法:/// /// 获得项目的根路径/// /// public......

  9. 如何在Vue项目中添加接口监听遮罩

    一、业务背景使用遮罩层来屏蔽用户的非正常操作,是前端经常使用的方式。但是在一些项目中,并没有对遮罩层进行统一管理,这......

  10. C# FTP上传下载 代码

    using System; using System.Collections.Generic; using Sy......